Access-File mit Command-Button öffnen??

[Achim Kerker]

Hallo Ihr dort draußen!
Ich möchte mit einen Makro-Prg, das über einen Command-Button gestartet
wird, ein Access-File nur zur Ansicht öffnen. Der Pfad des Access-Files wird
fest eingestellt und wird nicht verändert. Mir ist bisher nur gelungen mit
'Application.ActivateMicrosoftApp xlMicrosoftAccess' das Access-Programm zu
starten. Ich finde keine Möglichkeit eine spezielle Datei zu starten.

Kann jemand helfen ??!!
Danke Achim

[stefan onken]

hallo Achim,
das geht mit dem Shell-Befehl:

Shell " OfficePfad\msaccess.exe Pfad\deineDatei.mdb",vbnormalfocus

Um direkt eine Tabelle anzuzeigen:

Sub AccessTabelleAnzeigen()
'unter Extras/Verweise Verweis auf Microsoft Access Library
Const PFAD As String = "C:\test\deineDatei.mdb"
Const TABELLE As String = "Tabelle1"
Dim objAccess As Access.Application
Set objAccess = New Access.Application
objAccess.OpenCurrentDatabase PFAD
objAccess.DoCmd.OpenTable TABELLE
Set objAccess = Nothing
End Sub

In beiden Fällen kann man die Daten in Access ändern.
Um das zu verhindern, könntest du:
in Access ein Formular erstellen, dass eine Änderung der Daten nicht
zulässt, und dieses Form in obigem Code über DoCmd.OpenForm anzeigen oder
die Daten zunächst in Excel einlesen und in einem UserForm darstellen, ohne
die Access-Datei selbst anzuzeigen.

Gruß
stefan

Post by Achim Kerker
Hallo Ihr dort draußen!
Ich möchte mit einen Makro-Prg, das über einen Command-Button gestartet
wird, ein Access-File nur zur Ansicht öffnen. Der Pfad des Access-Files wird
fest eingestellt und wird nicht verändert. Mir ist bisher nur gelungen mit
'Application.ActivateMicrosoftApp xlMicrosoftAccess' das Access-Programm zu
starten. Ich finde keine Möglichkeit eine spezielle Datei zu starten.
Kann jemand helfen ??!!
Danke Achim

[Michael Schwimmer]

Hallo Achim,

Post by Achim Kerker
Hallo Ihr dort draußen!
Ich möchte mit einen Makro-Prg, das über einen Command-Button
gestartet wird, ein Access-File nur zur Ansicht öffnen. Der Pfad des
Access-Files wird fest eingestellt und wird nicht verändert. Mir ist
bisher nur gelungen mit 'Application.ActivateMicrosoftApp
xlMicrosoftAccess' das Access-Programm zu starten. Ich finde keine
Möglichkeit eine spezielle Datei zu starten.

mit der API ShellExecute wird eine Datei mit dem verknüpften Programm
gestartet. Das heißt, wenn Dateien mit der Endung .mdb mit Access
verknüpft sind, werden diese auch mit diesem Programm geöffnet (oder
gedruckt), je nach dem welche Möglichkeiten als Verben in der Registry
hinterlegt sind.

Private Declare Function ShellExecute Lib "shell32.dll" _
Alias "ShellExecuteA" (ByVal Fensterzugriffsnummer As Long, _
ByVal lpOperation_wie_Open_oder_Print As String, _
ByVal lpDateiname_incl_Pfad As String, _
ByVal lpZusätzliche_Startparameter As String, _
ByVal lpArbeitsverzeichnis As String, _
ByVal nGewünschte_Fenstergröße_der_Anwendung As Long) _
As Long

Private Const SW_HIDE = 0
Private Const SW_MAX = 10
Private Const SW_MAXIMIZE = 3
Private Const SW_MINIMIZE = 6
Private Const SW_NORMAL = 1
Private Const SW_SHOW = 5
Private Const SW_SHOWDEFAULT = 10
Private Const SW_SHOWMAXIMIZED = 3
Private Const SW_SHOWMINIMIZED = 2
Private Const SW_SHOWMINNOACTIVE = 7
Private Const SW_SHOWNORMAL = 1
Private Const SW_SHOWNOACTIVATE = 4

Sub Drucken()
ShellExecute 0&, "Print", "c:\Eigene Dateien\Asdf.doc", _
vbNullString, vbNullString, SW_SHOWMINNOACTIVE
End Sub

Sub Öffnen()
ShellExecute 0&, "Open", "c:\Eigene Dateien\Asdf.doc", _
vbNullString, vbNullString, SW_SHOWNORMAL
End Sub

MfG
Michael