Mehrere Zellen verbinden

[mk136]

Folgendes Problem:

Ich habe 4 nebeneinanderliegende Spalten, die miteinander verbunden
werden sollen. Das habe ich mit einer Formel in einer 5. Spalte
hinbekommen:
=E2&" "&F2&" "&G2&" "&H2

Nun sollen einige Inhalte noch zusätzliche Zeichen bekommen:
=E2&" "&F2&" ("&G2&") - "&H2
Der Inhalt von G2 soll also in Klammern stehen und der Inhalt von H2
soll durch ein Bindestrich optisch abgetrennt werden

Die die Formel soll auf viele Zeilen angewendet werden. Soweit erstmal
nicht das Problem für mich. Schwieriger finde ich, dass nicht immer
jede Zelle mit Inhalt gefüllt ist. Es geht nicht, dass einfach mal ein
() erscheint oder ein - am Ende eines Textes.

Liegt die Lösung da wieder bei VBA? Sollte ich dafür wieder ein Makro
programmieren? Leider kenne ich mich mit dieser Materie fast überhaupt
nicht aus. Würde mich aber über jeden Hinweis sehr freuen.

Viele Grüße,
Mandy

[Claus Busch]

Hallo Mandy,

Post by mk136
Ich habe 4 nebeneinanderliegende Spalten, die miteinander verbunden
werden sollen. Das habe ich mit einer Formel in einer 5. Spalte
=E2&" "&F2&" "&G2&" "&H2
=E2&" "&F2&" ("&G2&") - "&H2
Der Inhalt von G2 soll also in Klammern stehen und der Inhalt von H2
soll durch ein Bindestrich optisch abgetrennt werden
Die die Formel soll auf viele Zeilen angewendet werden. Soweit erstmal
nicht das Problem für mich. Schwieriger finde ich, dass nicht immer
jede Zelle mit Inhalt gefüllt ist. Es geht nicht, dass einfach mal ein
() erscheint oder ein - am Ende eines Textes.
Liegt die Lösung da wieder bei VBA? Sollte ich dafür wieder ein Makro
programmieren? Leider kenne ich mich mit dieser Materie fast überhaupt
nicht aus. Würde mich aber über jeden Hinweis sehr freuen.

probiers mal so:
=WENN(UND(G2="";H2="");E2&" "&F2;WENN(G2="";E2&" "&F2&" - "& H2;WENN(H2="";E2&" "&F2&" ("&G2&" )";E2&" "&F2&" ("&G2&") "&"- "&H2)))

[Alexander Wolff]

Post by Claus Busch

Post by mk136
=E2&" "&F2&" "&G2&" "&H2
=E2&" "&F2&" ("&G2&") - "&H2

=WENN(UND(G2="";H2="");E2&" "&F2;WENN(G2="";E2&" "&F2&" - "&
H2;WENN(H2="";E2&" "&F2&" ("&G2&" )";E2&" "&F2&" ("&G2&") "&"-
"&H2)))

oder so:
=WENN(E3="";"";E3&" ")&WENN(F3="";"";F3&" ")
&WENN(G3="";"";"("&G3&") ")&WENN(H3="";"";"- "&H3)

(mich hat es deshalb gereizt, weil ich den Bedarf für UND nicht kapiert
habe, sondern jeden einzelnen Parameter gesondert behandle; vielleicht gibt
es aber doch einen Grund?)

[mk136]

Da ihr mir alle so toll geholfen habt, habe ich mich gleich ganz
optimistisch auf meine weiteres Aufgaben gestürzt und bin auch gleich
wieder beim nächsten "Zellen verbinden" gestolpert:

Ich möchte einfach zwei Zellen verbinden, die jeweils ein Datum
enthalten. Zwischen beide Datumsangaben soll ein -
=A2&" - "&B2

Dabei entsteht dann sowas: GanzeZahl - GanzeZahl

Ich habe auch schon fleißig aber leider vergeblich nach diesem Problem
gegooglet :o(

Würde mich wie immer sehr über jeden Hinweis freuen.

Viele Grüße,
Mandy

[mk136]

Noch ein Nachtrag zu meinem ersten Problem:

Die Robert-Variante hatte bei mir leider nicht funktioniert. So fiel
die Entscheidung für die Claus-Variante also nicht so schwer.

[Alexander Wolff]

Post by mk136
Da ihr mir alle so toll geholfen habt, habe ich mich gleich ganz
optimistisch auf meine weiteres Aufgaben gestürzt und bin auch gleich
Ich möchte einfach zwei Zellen verbinden, die jeweils ein Datum
enthalten. Zwischen beide Datumsangaben soll ein -
=A2&" - "&B2
Dabei entsteht dann sowas: GanzeZahl - GanzeZahl
Ich habe auch schon fleißig aber leider vergeblich nach diesem Problem
gegooglet :o(
Würde mich wie immer sehr über jeden Hinweis freuen.

=TEXT(A2;"TT.MM.JJ")&" - "&TEXT(B2;"TT.MM.JJ")

[mk136]

Mannoman, das geht ja hier wie´s Brezel backen ;o)

Herzlichen Dank, Alexander!

[mk136]

Und noch ein Nachtrag für Alexander,
Habe eben auch deine Variante für mein ersteres Problem probiert.
Funktionierte auch prima!

[mk136]

Und noch ein Nachtrag für Alexander,
Habe eben auch deine Variante für mein ersteres Problem probiert.
Funktionierte auch prima!

Danke nochmals an euch alle!!!
Mandy

[mk136]

Hallo,

leider bin ich immer noch nicht mit meiner Tabelle fertig :o(
Jetzt habe ich eine Sache, bei der mir auch nicht die schlauen Bücher
helfen, die ich mir inzwischen besorgt habe ...

Würde mich sehr freuen, wenn sich wieder jemand bereit erklären
würde mir zu helfen.

Also das Problem:
ich habe 2 Saplten/Zellen die miteinander verbunden werden sollen.
Allerdings ist es so, dass in Zelle 1 mehrere Kombinationen aus
Buchstaben und Zahlen (Notation) stehen Bsp. A10 die nächste Notation
ist durch ein ^ abgetrennt.
A10^B20^C30

In der Zelle 2 steht der dazugehörige Text. Die Texte sind wieder
durch ^ voneinander getrennt.
text^noch mehr text^texttext

Habe ich das soweit verständlich erklärt?

Nun sollen also die Inhalte der Zelle 2 zur Zelle 1 zusammengeführt
werden. Es soll also herauskommen:
A10 text B20 noch mehr text C30 texttext
und am besten alles auf eine neue Zeile

Kann man sowas mit Excel machen?

Freue mich wie sonst auch über jeden Hinweis.

Schöne Grüße und einen schönen Feierabend,
Mandy

[Claus Busch]

Hallo Mandy,

Post by mk136
leider bin ich immer noch nicht mit meiner Tabelle fertig :o(
Jetzt habe ich eine Sache, bei der mir auch nicht die schlauen Bücher
helfen, die ich mir inzwischen besorgt habe ...
Würde mich sehr freuen, wenn sich wieder jemand bereit erklären
würde mir zu helfen.
ich habe 2 Saplten/Zellen die miteinander verbunden werden sollen.
Allerdings ist es so, dass in Zelle 1 mehrere Kombinationen aus
Buchstaben und Zahlen (Notation) stehen Bsp. A10 die nächste Notation
ist durch ein ^ abgetrennt.
A10^B20^C30
In der Zelle 2 steht der dazugehörige Text. Die Texte sind wieder
durch ^ voneinander getrennt.
text^noch mehr text^texttext
Habe ich das soweit verständlich erklärt?
Nun sollen also die Inhalte der Zelle 2 zur Zelle 1 zusammengeführt
A10 text B20 noch mehr text C30 texttext
und am besten alles auf eine neue Zeile
Kann man sowas mit Excel machen?

du könntest deine neben deinen Spalten so viele neue leere Spalten
einfügen, wie du einzelne Notationen in der Zelle hast. Dann Spalte
markieren => Text in Spalten => Getrennt. Als Trennzeichen dein "^"
eingeben und dir die Einzelteile trennen und danach wieder zusammensetzen.
Falls du dir die Mühe und den Umweg nicht machen willst, probiere es mit
dieser Formel:
Wenn ich dich richtig verstanden habe und deine erste Zelle A2 und die
zweite Zelle B2 ist, sollte es so funktionieren:
=LINKS(A2;FINDEN("^";A2)-1)&" "&LINKS(B2;FINDEN("^";B2)-1)&" "&TEIL(A2;LÄNGE(LINKS(A2;FINDEN("^";A2)))+1;FINDEN("#";WECHSELN(A2;"^";"#";2))-LÄNGE(LINKS(A2;FINDEN("^";A2)))-1)&" "&TEIL(B2;LÄNGE(LINKS(B2;FINDEN("^";B2)))+1;FINDEN("#";WECHSELN(B2;"^";"#";2))-LÄNGE(LINKS(B2;FINDEN("^";B2)))-1)&" "&RECHTS(A2;LÄNGE(A2)-FINDEN("#";WECHSELN(A2;"^";"#";2)))&" "&RECHTS(B2;LÄNGE(B2)-FINDEN("#";WECHSELN(B2;"^";"#";2)))

[mk136]

Hallo Claus,

wiedermal ganz herzlichen Dank für die schnelle Antwort!

Post by Claus Busch
du könntest deine neben deinen Spalten so viele neue leere Spalten
einfügen, wie du einzelne Notationen in der Zelle hast. Dann Spalte
markieren => Text in Spalten => Getrennt. Als Trennzeichen dein "^"
eingeben und dir die Einzelteile trennen und danach wieder zusammensetzen.

Funktioniert prima und ich habe auch wieder was dazu gelernt,
allerdings wie du schon festgestellt hast, wird das recht mühevoll, da
es sich irgendwann um eine riesige Tabelle mit hunderten von
Datensätzen handeln wird. Momentan versuche ich erst einmal
herauszufinden, ob man das was wir machen wollen mit Excel machbar ist.

Zur Not würde dieser Weg aber auch gehen

Post by Claus Busch
Falls du dir die Mühe und den Umweg nicht machen willst, probiere es mit
Wenn ich dich richtig verstanden habe und deine erste Zelle A2 und die
=LINKS(A2;FINDEN("^";A2)-1)&" "&LINKS(B2;FINDEN("^";B2)-1)&" "&TEIL(A2;LÄNGE(LINKS(A2;FINDEN("^";A2)))+1;FINDEN("#";WECHSELN(A2;"^";"#";2))-LÄNGE(LINKS(A2;FINDEN("^";A2)))-1)&" "&TEIL(B2;LÄNGE(LINKS(B2;FINDEN("^";B2)))+1;FINDEN("#";WECHSELN(B2;"^";"#";2))-LÄNGE(LINKS(B2;FINDEN("^";B2)))-1)&" "&RECHTS(A2;LÄNGE(A2)-FINDEN("#";WECHSELN(A2;"^";"#";2)))&" "&RECHTS(B2;LÄNGE(B2)-FINDEN("#";WECHSELN(B2;"^";"#";2)))

Leider hat das nur für die ersten zwei - ich nenne es mal Notationen -
funktioniert. Die restlichen Texte werden aber mit angehangen. Müßte
man dazu die Formel noch erweitern?
Außerdem habe ich auch hier wieder das Problem, dass in einigen
Datensätze keine Werte (Notaionen) vorhanden sind. Müßte man hier
wieder die Wenn-Funktion verwenden?

Gibt es eine Zeichen bzw. eine Zeichenkette um einen Zeilenumbruch im
Text zu erzeugen? Das würde ich gerne noch in die Formel einbaune
wollen.

Viele Grüße,
Mandy

[Claus Busch]

Hallo Mandy,

Post by mk136
Funktioniert prima und ich habe auch wieder was dazu gelernt,
allerdings wie du schon festgestellt hast, wird das recht mühevoll, da
es sich irgendwann um eine riesige Tabelle mit hunderten von
Datensätzen handeln wird. Momentan versuche ich erst einmal
herauszufinden, ob man das was wir machen wollen mit Excel machbar ist.
Zur Not würde dieser Weg aber auch gehen

Post by Claus Busch
Falls du dir die Mühe und den Umweg nicht machen willst, probiere es mit
Wenn ich dich richtig verstanden habe und deine erste Zelle A2 und die
=LINKS(A2;FINDEN("^";A2)-1)&" "&LINKS(B2;FINDEN("^";B2)-1)&" "&TEIL(A2;LÄNGE(LINKS(A2;FINDEN("^";A2)))+1;FINDEN("#";WECHSELN(A2;"^";"#";2))-LÄNGE(LINKS(A2;FINDEN("^";A2)))-1)&" "&TEIL(B2;LÄNGE(LINKS(B2;FINDEN("^";B2)))+1;FINDEN("#";WECHSELN(B2;"^";"#";2))-LÄNGE(LINKS(B2;FINDEN("^";B2)))-1)&" "&RECHTS(A2;LÄNGE(A2)-FINDEN("#";WECHSELN(A2;"^";"#";2)))&" "&RECHTS(B2;LÄNGE(B2)-FINDEN("#";WECHSELN(B2;"^";"#";2)))

Leider hat das nur für die ersten zwei - ich nenne es mal Notationen -
funktioniert. Die restlichen Texte werden aber mit angehangen. Müßte
man dazu die Formel noch erweitern?
Außerdem habe ich auch hier wieder das Problem, dass in einigen
Datensätze keine Werte (Notaionen) vorhanden sind. Müßte man hier
wieder die Wenn-Funktion verwenden?

ich bin von der Fragestellung davon ausgegangen, dass jeweils 3 getrennte
Strings in der Zelle stehen. Wenn es noch mehr und auch unterschiedlich
ciele sein können, müsste man diese Formel erweitern. Aber dann wird es
noch unübersichtlicher. Ich würde dann eher dazu tendieren, die betroffenen
Spalten in ein extra Tabellenblatt zu kopieren, über Text in Spalten zu
trennen und dann im Originaltabellenblatt auf diese getrennten Werte
zuzugreifen.
Schau dir auch mal diese Formeln an. Da kannst du auch einiges auf deine
Bedingungen umändern:
http://www.excelformeln.de/formeln.html?welcher=301
http://www.excelformeln.de/formeln.html?welcher=326
http://www.excelformeln.de/formeln.html?welcher=158

Post by mk136
Gibt es eine Zeichen bzw. eine Zeichenkette um einen Zeilenumbruch im
Text zu erzeugen? Das würde ich gerne noch in die Formel einbaune
wollen.

Zeilenumbruch ist ZEICHEN(10). Dazu musst du aber auch bei Format => Zellen
=> Ausrichtung die Option "Zeilenumbruch" aktivieren, sonst werden dir nur
Kästchen angezeigt.

[mk136]

Hallo Claus,

wieder herzlichen Dank für die Infos! Bei Gelegenheit werde ich mich
mal in die Formeln hineinvertiefen. Ich werde dann wohl doch die
erstere Variant nehmen, da sie im Moment doch die schnellere ist.

Mit freundlichen Grüßen,
Mandy Krüpfganz

[mk136]

Der Vollständigkeit halber hier meine Formel für das Verbinden
mehrerer Zellen, wobei nach zwei verbundenen Zellen auf einer neuen
Zeile weitergeschrieben wird:

=WENN(A1="";"";VERKETTEN(A1;" - ";E1;)) &ZEICHEN(10)
&WENN(B1="";"";VERKETTEN(B1;" - ";F1;)) &ZEICHEN(10)
&WENN(C1="";"";VERKETTEN(C1;" - ";G1;)) &ZEICHEN(10)
&WENN(D1="";"";VERKETTEN(D1;" - ";H1;)) &ZEICHEN(10)

Nun habe ich aber wieder eine Frage. Das müßte dann aber auch die
letzte zu diesem Thema sein ...

Wie ich schon geschrieben hatte, habe ich eine große Tabelle. Aus
dieser Tabelle wurden im letzten Schritt zwei Spalten ausgegliedert.
Über "Daten > Text in Spalten" wurden deren Inhalte "aufgelöst" und
mit o.g. Formel wieder neu zusammen gefügt.
Nun soll der neue Text, der jetzt nur noch in einer Spalte steht wieder
zurück in die große Tabelle. Das will funktioniert leider nicht so
einfach. Es wird die Formel übernommen und dann habe ich Inhalte der
Gesamttabelle, die ich nicht haben will. Ich müßte also nochmals an
der Formel herumbasteln.
Kann man den Inhalt, der durch Formeln entstanden ist irgendwie
"eigenständig" machen. Ich würde auch gerne überflüssige Spalten in
der Gesamttabelle löschen, weil es übersichtlicher wird. Geht aber
momentan nicht, weil ich immer alle Inhalte benötige. Die Formeln
funkionieren ja sonst auch nicht.

Freue mich über jeden Hinweis,

Viele Grüße,
Mandy

[mk136]

Diesmal kann ich mir die Frage selbst beantworten :o)
Vielleicht gibt es aber noch eine andere Möglichkeit.
Ich kopiere die entsprechende Spalte. Gehe dann auf "Inhalte
einfügen", wähle: "Werte und Zahlenformate".

Danke also an alle für eure Hilfe!!! Ich habe dank euch doch ganz
schön viel dazu gelernt :o)

Nochmals viele Grüße und ein schönes WE,
Mandy

[Claus Busch]

Hallo Mandy,

Post by mk136
Der Vollständigkeit halber hier meine Formel für das Verbinden
mehrerer Zellen, wobei nach zwei verbundenen Zellen auf einer neuen
=WENN(A1="";"";VERKETTEN(A1;" - ";E1;)) &ZEICHEN(10)
&WENN(B1="";"";VERKETTEN(B1;" - ";F1;)) &ZEICHEN(10)
&WENN(C1="";"";VERKETTEN(C1;" - ";G1;)) &ZEICHEN(10)
&WENN(D1="";"";VERKETTEN(D1;" - ";H1;)) &ZEICHEN(10)

gibt es denn zu jedem Wert in A1 auch einen Wert in E1 und ungekehrt usw.?
Die Werte treten also immer paarweise auf?Wrum benötigst du noch den
Zeilenumbruch am Ende?
Etwas kürzer könntest du die Formel gestalten, wenn du statt VERKETTEN
einfach den &-Operator nehmen würdest:
=WENN(A1="";"";A1&" - "&E1)&ZEICHEN(10)
&WENN(B1="";"";B1&" - "&F1)&ZEICHEN(10)
&WENN(C1="";"";C1&" - "&G1)&ZEICHEN(10)
&WENN(D1="";"";D1&" - "&H1)

Deine Frage hast du ja schon selbst beantwortet. Aber du könntest auch
einfach nur Werte einfügen, danach den ganzen Bereich markieren und über
Format => Zellen => Ausrichtung den Zeilenumbruch auf einen Rutsch für alle
benötigten Zellen aktivieren.

[mk136]

Hallo Claus

Post by Claus Busch

Post by mk136
=WENN(A1="";"";VERKETTEN(A1;" - ";E1;)) &ZEICHEN(10)
&WENN(B1="";"";VERKETTEN(B1;" - ";F1;)) &ZEICHEN(10)
&WENN(C1="";"";VERKETTEN(C1;" - ";G1;)) &ZEICHEN(10)
&WENN(D1="";"";VERKETTEN(D1;" - ";H1;)) &ZEICHEN(10)

gibt es denn zu jedem Wert in A1 auch einen Wert in E1 und ungekehrt usw.?

Genau so ist es. Und zu B1 gibt es einen Wert in F1 usw.

Post by Claus Busch
Die Werte treten also immer paarweise auf?
Wrum benötigst du noch den Zeilenumbruch am Ende?

den benötige ich natürlich nicht. Da war ich hier wohl mit meiner
Formel zu voreilig - vor lauter Freude ;o)

Post by Claus Busch
Etwas kürzer könntest du die Formel gestalten, wenn du statt VERKETTEN
=WENN(A1="";"";A1&" - "&E1)&ZEICHEN(10)
&WENN(B1="";"";B1&" - "&F1)&ZEICHEN(10)
&WENN(C1="";"";C1&" - "&G1)&ZEICHEN(10)
&WENN(D1="";"";D1&" - "&H1)

diese Variante gefällt mir noch viel besser :o)

Post by Claus Busch
Deine Frage hast du ja schon selbst beantwortet. Aber du könntest auch
einfach nur Werte einfügen, danach den ganzen Bereich markieren und über
Format => Zellen => Ausrichtung den Zeilenumbruch auf einen Rutsch für alle
benötigten Zellen aktivieren.

das wird nicht ausreichen, weil die Daten (die aus einer Datenbank
ausgelesen wurden) noch in Word "ausfließen" sollen. Und dafür
möchte ich ein paar Daten vorher schon so gut es geht zusammen fügen
und vorformatieren.

Ich werde also bestimmt noch eine Weile hier in denGruppen unterwegs
sein ...

Schönen Feierabend, vielen Dank und ein erholsames WE,
Mandy

[Robert Gelbmann]

Hallo Mandy!

Post by mk136
[...]
=E2&" "&F2&" ("&G2&") - "&H2
Der Inhalt von G2 soll also in Klammern stehen und der Inhalt von H2
soll durch ein Bindestrich optisch abgetrennt werden
Die die Formel soll auf viele Zeilen angewendet werden. Soweit
erstmal
nicht das Problem für mich. Schwieriger finde ich, dass nicht immer
jede Zelle mit Inhalt gefüllt ist. Es geht nicht, dass einfach mal ein
() erscheint oder ein - am Ende eines Textes.
Liegt die Lösung da wieder bei VBA?

Nein, die WENN-Funktion sollte Dir da genügen:

(1 Zeile)
=E2 & " " & F2 & WENN(ISTLEER(G2);"";" (" & G2 & ")") &
WENN(ISTLEER(H2);"";" - " & H2)

[mk136]

Hall Claus, Hallo Robert

ganz herzlichen Dank für die super schnelle Hilfe!!!
Freu mich wirklich sehr darüber :o)))))

Viele Grüße,
Mandy