Summenprodukt: gleiche Werte nur einmal berücksichtigen

[Jens]

Hallo!

Excel 2007

Ich habe eine Spalte L mit Zahlen. In einer anderen Zelle möchte ich jetzte
die Anzahl der Zahlen mit bestimmten Kriterien zählen. Dies mache ich mit
folgender Formel: SUMMENPRODUKT(($L$21:$L$38={"52"."53"."54"."55"})*1).

Jetzt zu meinem Problem: In der obigen Formel ist ein Kriterium die Zahl 55.
Jetzt kommt aber die Zahl 55 mehrmals in meiner Auflistung vor, ich möchte
aber, dass alle Zahlen nur einmal gezählt werden.

Hat einer eine Idee? Ich habe bisher nichts gefunden.

Grüße Jens

[Marcus Friebe]

Hallo Jens

Post by Jens
[...]
Ich habe eine Spalte L mit Zahlen. In einer anderen Zelle möchte ich
jetzte die Anzahl der Zahlen mit bestimmten Kriterien zählen. Dies
SUMMENPRODUKT(($L$21:$L$38={"52"."53"."54"."55"})*1).
Jetzt zu meinem Problem: In der obigen Formel ist ein Kriterium die
Zahl 55. Jetzt kommt aber die Zahl 55 mehrmals in meiner Auflistung
vor, ich möchte aber, dass alle Zahlen nur einmal gezählt werden.
[...]

Versuche es bitte mal so:

=SUMME(WENN((L21:L28<>"");1/ZÄHLENWENN(L21:L28;L21:L28);0))

Und die Eingabe abschliessen mit Strg-Shift-Enter

[Dietmar Vollmeier]

Servus Jens!

*Jens* schrieb am 18.11.2007 um 11:13 Uhr...

Post by Jens
Ich habe eine Spalte L mit Zahlen. In einer anderen Zelle möchte ich
jetzte die Anzahl der Zahlen mit bestimmten Kriterien zählen. Dies
SUMMENPRODUKT(($L$21:$L$38={"52"."53"."54"."55"})*1).
Jetzt zu meinem Problem: In der obigen Formel ist ein Kriterium die
Zahl 55. Jetzt kommt aber die Zahl 55 mehrmals in meiner Auflistung
vor, ich möchte aber, dass alle Zahlen nur einmal gezählt werden.
Hat einer eine Idee? Ich habe bisher nichts gefunden.

Denkbar wäre eine Lösung über eine Hilfsspalte.
Füge folgende Formel in Zelle M21 ein und kopiere sie nach unten bis M38.

=WENN(SUMME(WENN(L$21:L$38="";0;1/ZÄHLENWENN(L$21:L$38;L$21:L$38))) < ZEILE(L1);"";INDEX(L:L;KKLEINSTE(WENN(ZÄHLENWENN(BEREICH.VERSCHIEBEN(L$1;;;ZEILE($21:$38));L$21:L$38)=1;ZEILE($21:$38));ZEILE(L1))))

Es handelt sich dabei um eine Matrix-Formel! Daher bitte mit
[Strg]+[Shift]+[Enter] abschließen!

Ändere anschließend deine Formel auf

=SUMMENPRODUKT(($M$21:$M$38={52.53.54.55})*1)

HTH

und tschüss,
Didi

[Jens]

Danke Dietmar!

Diese Lösung hat mir einige Stunden weiteres Probieren und weitere Recherche
erspart. Schönen Sonntag noch!

Gruß Jens

Post by Dietmar Vollmeier
Servus Jens!
*Jens* schrieb am 18.11.2007 um 11:13 Uhr...

Post by Jens
Ich habe eine Spalte L mit Zahlen. In einer anderen Zelle möchte ich
jetzte die Anzahl der Zahlen mit bestimmten Kriterien zählen. Dies
SUMMENPRODUKT(($L$21:$L$38={"52"."53"."54"."55"})*1).
Jetzt zu meinem Problem: In der obigen Formel ist ein Kriterium die
Zahl 55. Jetzt kommt aber die Zahl 55 mehrmals in meiner Auflistung
vor, ich möchte aber, dass alle Zahlen nur einmal gezählt werden.
Hat einer eine Idee? Ich habe bisher nichts gefunden.

Denkbar wäre eine Lösung über eine Hilfsspalte.
Füge folgende Formel in Zelle M21 ein und kopiere sie nach unten bis M38.
=WENN(SUMME(WENN(L$21:L$38="";0;1/ZÄHLENWENN(L$21:L$38;L$21:L$38))) < ZEILE(L1);"";INDEX(L:L;KKLEINSTE(WENN(ZÄHLENWENN(BEREICH.VERSCHIEBEN(L$1;;;ZEILE($21:$38));L$21:L$38)=1;ZEILE($21:$38));ZEILE(L1))))
Es handelt sich dabei um eine Matrix-Formel! Daher bitte mit
[Strg]+[Shift]+[Enter] abschließen!
Ändere anschließend deine Formel auf
=SUMMENPRODUKT(($M$21:$M$38={52.53.54.55})*1)
HTH
und tschüss,
Didi
--
Wir sitzen alle in einem Boot. Die einen angeln, wir rudern.

[Dietmar Vollmeier]

*Jens* schrieb am 18.11.2007 um 12:45 Uhr...

Post by Jens
Danke Dietmar!
Diese Lösung hat mir einige Stunden weiteres Probieren und weitere
Recherche erspart. Schönen Sonntag noch!

Gerne und gleichfalls :-)

[TOFU entsorgt [1]]

und tschüss,
Didi

Fußnötiges:
===========
[1] http://de.wikipedia.org/wiki/TOFU

[Claus Busch]

Hallo Dietmar, hallo Jens,

Post by Dietmar Vollmeier
Denkbar wäre eine Lösung über eine Hilfsspalte.
Füge folgende Formel in Zelle M21 ein und kopiere sie nach unten bis M38.
=WENN(SUMME(WENN(L$21:L$38="";0;1/ZÄHLENWENN(L$21:L$38;L$21:L$38))) < ZEILE(L1);"";INDEX(L:L;KKLEINSTE(WENN(ZÄHLENWENN(BEREICH.VERSCHIEBEN(L$1;;;ZEILE($21:$38));L$21:L$38)=1;ZEILE($21:$38));ZEILE(L1))))
Es handelt sich dabei um eine Matrix-Formel! Daher bitte mit
[Strg]+[Shift]+[Enter] abschließen!
Ändere anschließend deine Formel auf
=SUMMENPRODUKT(($M$21:$M$38={52.53.54.55})*1)

es geht auch so:
Ab M21 : =ZÄHLENWENN($L$21:L21;L21) und bis M38 nach unten ziehen.
Dann als Auswertung:
=SUMMENPRODUKT(($L$21:$L$38={52.53.54.55})*($M$21:$M$38=1))


Mit freundlichen Grüssen
Claus Busch

[Klaus "Perry" Pago]

Hallo Jens,

Post by Jens
Hallo!
Excel 2007
Ich habe eine Spalte L mit Zahlen. In einer anderen Zelle möchte ich jetzte
die Anzahl der Zahlen mit bestimmten Kriterien zählen. Dies mache ich mit
folgender Formel: SUMMENPRODUKT(($L$21:$L$38={"52"."53"."54"."55"})*1).
Jetzt zu meinem Problem: In der obigen Formel ist ein Kriterium die Zahl 55.
Jetzt kommt aber die Zahl 55 mehrmals in meiner Auflistung vor, ich möchte
aber, dass alle Zahlen nur einmal gezählt werden.
Hat einer eine Idee? Ich habe bisher nichts gefunden.

hier mal eine Matrixformel-Lösung ohne Hilfsspalten:

=SUMME(WENN(MMULT(MTRANS({"52"."53"."54"."55"}=$L$21:$L$38)*1;ZEILE(1:18)/ZEILE(1:18));1))

mit dem Drei-Finger-Tasten-Griff STRG SHIFT RETURN eingeben (sonst geht es
nicht)

Gruß
Klaus
------
Nur wer fragt, bringt sich und andere weiter. Aber diejenigen, die
antworten, haben sich auch ein Feedback verdient.

[Alexander Wolff]

=SUMMENPRODUKT(--(ZÄHLENWENN($L$21:$L$38;"5"&ZEILE(2:5))>0))