Fußballergebnisse

[Ralf11]

Hallo,
ich möchte gerne Fußballergebnisse mit einer Formel in Excel 2007 auswerten
lassen.
Ich weiss leider nicht wie diese Formel aufgebaut wird, für Hilfe bin ich
sehr dankbar.
Beispiel:
Das erspielte Ergebniss ist 3:2 (Zelle A1)
Das getippte Ergebniss ist 2:1 (Zelle A2) = Tendenz = 1 Punkt
Gleich getipptes Ergebniss = 3 Punkte
Kein übereinstimmendes Ergebniss (z.B. 2:3 oder unentschieden) = 0 Punkte

Danke,
Ralf

[Andreas Stoye]

Hi Ralf,

Post by Ralf11
ich möchte gerne Fußballergebnisse mit einer Formel in Excel 2007 auswerten
lassen.
Ich weiss leider nicht wie diese Formel aufgebaut wird, für Hilfe bin ich
sehr dankbar.
Das erspielte Ergebniss ist 3:2 (Zelle A1)
Das getippte Ergebniss ist 2:1 (Zelle A2) = Tendenz = 1 Punkt
Gleich getipptes Ergebniss = 3 Punkte
Kein übereinstimmendes Ergebniss (z.B. 2:3 oder unentschieden) = 0 Punkte

Formatiere A1 und A2 mit Format - Zellen als Text. Folgende Formel
zeigt dein Ergebnis:
=WENN(UND(LINKS(A1;1)=LINKS(A2;1);RECHTS(A1;1)=RECHTS(A2;1));3;WENN(ODER(UND(LINKS(A1;1)>RECHTS(A1;1);LINKS(A2;1)>RECHTS(A2;1));UND(LINKS(A1;1)=RECHTS(A1;1);LINKS(A2;1)=RECHTS(A2;1));UND(LINKS(A1;1)<RECHTS(A1;1);LINKS(A2;1)<RECHTS(A2;1)));1;0))

Funktioniert aber nur für einstellige Ergebnisse. 10:0 ist mit der
Formel identisch mit 1:0. Ich empfehle das Ergebnis auf 3 Zellen
aufzuteilen, z.B. 3:1: 3 in A1, : in B1, 1 in C1 usw. Die Auswertung
ist analog, bloß wird kein Text verglichen sondern Zahlen, also z.B.
LINKS(A1;1)=LINKS(A2;1) wird ersetzt durch A1=A2.

mfg Andreas Stoye

[Alexander Wolff]

Post by Ralf11
Das erspielte Ergebniss ist 3:2 (Zelle A1)
Das getippte Ergebniss ist 2:1 (Zelle A2) = Tendenz = 1 Punkt
Gleich getipptes Ergebniss = 3 Punkte
Kein übereinstimmendes Ergebniss (z.B. 2:3 oder unentschieden) = 0 Punkte

Andreas' 1-Zellenversuch Versuch in allen Ehren, aber ich mag es dann doch
einfacher, indem ich 4 Zellen A3:A6 zusätzlich verwende:

A3: =--LINKS(A1;FINDEN(":";A1)-1) 'Heim-Tipp
A4: =--LINKS(A2;FINDEN(":";A2)-1) 'Gast-Tipp
A5: =--RECHTS(A1;LÄNGE(A1)-LÄNGE(A3)-1) 'Heim-Resultat
A6: =--RECHTS(A2;LÄNGE(A2)-LÄNGE(A4)-1) 'Gast-Resultat

Nun die Auswertung:

A7: =(A5=A6)*(A4=A3)+(A5-A6=A3-A4)+(VORZEICHEN(A5-A3)=VORZEICHEN(A6-A4))

Achtung: A7 ist hier ausführlicher, als Du es möchtest:
- 3 Punkte: So wie bei Dir.
- Für 3:2 gibt es bei mir 2 Punkte, weil die Tor-Differenz gleich ist, nicht
nur die Tendenz. Das gilt dann allerdings auch für alle Unentschieden!
- Bei Nur-Tendenzgleichheit (also etwa 3:1) gibt es bei mir 1 Punkt.

Andreas' Einstelligkeitsrestriktion fällt außerdem weg.

Möchtest Du trotzdem lieber genau Deine Aufgabenstellung gelöst haben, geht
es etwas kürzer so:

A7: =2*(A5=A6)*(A4=A3)+(VORZEICHEN(A5-A3)=VORZEICHEN(A6-A4))

d.h., der mittlere Term fällt weg und der vordere hat doppelt Gewicht.