SVERWEIS- Formel kürzer

[Hans Alborg]

Hallo Gruppe,

Ich möchte die Summe einiger Spalten zusammenzählen und das Ergebnis in
Zelle AT23 bekommen.

In den Zeilen A18 bis A32 kann ein Text vorkommen, in dessen Zeile die
Zählung erfolgen soll.

Die Spalten wo die Zahlen auftauchen können sind O, S, W, AA und AE.
Die stehen nebeneinander, was fehlt geht durch verbundene Zellen
"verloren".

Meine lange und bestimmt umständliche Formel lautet:

=SUMME(WENN(ISTZAHL(SVERWEIS("Abgeltung";A18:AH32;15;FALSCH));SVERWEIS("Abgeltung";A18:AH32;15;FALSCH);0);WENN(ISTZAHL(SVERWEIS("Abgeltung";A18:AH32;19;FALSCH));SVERWEIS("Abgeltung";A18:AH32;19;FALSCH);0);WENN(ISTZAHL(SVERWEIS("Abgeltung";A18:AH32;23;FALSCH));SVERWEIS("Abgeltung";A18:AH32;23;FALSCH);0);WENN(ISTZAHL(SVERWEIS("Abgeltung";A18:AH32;27;FALSCH));SVERWEIS("Abgeltung";A18:AH32;27;FALSCH);0);WENN(ISTZAHL(SVERWEIS("Abgeltung";A18:AH32;31;FALSCH));SVERWEIS("Abgeltung";A18:AH32;31;FALSCH);0))

Das Kernstück:

(WENN(ISTZAHL(SVERWEIS("Abgeltung";A18:AH32;15;FALSCH));SVERWEIS("Abgeltung";A18:AH32;15;FALSCH);0)

Der erste Teil soll #Wert abfangen, wenn in den Matrixzellen Formeln
enthalten sind.
Ist das nicht der Fall, möchte ich die Zahl aus der Matrix A18:R32 bekommen
die in der Zeile zu finden ist wo "Abgeltung" steht.

Mir schwebt vor das in der Form SUMME(A:Z) zu verkürzen, aber damit hatte
ich keinen Erfolg.
Geht das überhaupt? Vielleich klappt es nicht weil die Spaltenindizes
Lücken aufweisen (15,19,23, 27 und 31)?

Oder... weiß jemand eine andere,kürzere Art das Ergebnis zu bekommen?

Hans

[Boris X]

Hi Hans,

{=SUMME((A18:A32="Abgeltung")*WENN(ISTZAHL(O18:AE32);O18:AE32))}

Als Arrayformel:
{geschweifte Klammern} nicht mit eingeben, sondern Formeleingabe mi
gleichzeitig Strg-Shift-Enter abschließen. Das erzeugt sie.

[Hans Alborg]

Hallo Boris,

"Boris X" schrieb...

Post by Boris X
{=SUMME((A18:A32="Abgeltung")*WENN(ISTZAHL(O18:AE32);O18:AE32))}
{geschweifte Klammern} nicht mit eingeben, sondern Formeleingabe mit
gleichzeitig Strg-Shift-Enter abschließen. Das erzeugt sie.

Das ist die Lösung! Klappt prima.

schönen Sonntag,

Hans