Add-Ins aufrufen

Melanie Breden

2003-08-01 09:50:12 UTC

Hallo Joachim,

"Joachim" schrieb:
Ich habe in einer Excel Datei ein Makro erstellt und die
Datei dann als Add-In (xla.-Datei im Add-In Ordner)
abgespeichert.

Wie ich dieses Add-In "verfügbar" mache, ist mir klar: In
Excel-Extras-Add_In_Manager auf Durchsuchen klicken und
dann meine xla-datei angeben. (im Add-In-manager wird
diese dann mit einem Hacken angezeigt).

Jetz ist das Add-In bei jedem Excel Start "verfügbar",
aber wie führe ich jetzt das im Add-In befindliche Makro
aus???

Ich will nicht immer den VBA-Editor aufrufen und über den
Projektexplorer das Makro im Add-in anwählen und
ausführen. Es soll direkt von einer neuen Excel-Tabelle
aus funktionieren! aber wie?
<<<

Makros werden in Add-Ins zwar nicht in der Liste über Extras | Makro | Makros aufgeführt, aber du
kannst darauf zugreifen, indem du in die oberste Zeile den Namen der Prozedur eingibst.

Oder erstelle im Workbook_Open des Add-Ins ein Schaltfläche auf einer Symbolleiste
und weise ihr das Makro zu:

Zum Beispiel:
Private Sub Workbook_Open()
Dim CmdBarPop As CommandBarPopup
Dim cmdBarBtn As CommandBarButton

On Error Resume Next
Application.CommandBars(1).Controls("Mein Menü").Delete
On Error GoTo 0

Set CmdBarPop = Application.CommandBars(1).Controls.Add( _
Type:=msoControlPopup, _
Temporary:=True)

CmdBarPop.Caption = "&Mein Menü"
Set cmdBarBtn = CmdBarPop.Controls.Add

With cmdBarBtn
.Caption = "MeinMakro"
.OnAction = "Makro1"
.FaceId = 59
End With
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
On Error Resume Next
Application.CommandBars(1).Controls("Mein Menü").Delete
End Sub

--
Mit freundlichen Grüßen
Melanie Breden

_____________________
[Microsoft MVP für Excel]